home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Amiga Plus Extra 1997 #1
/
Amiga Plus Extra 1997 #1.iso
/
programme
/
tools
/
adam-demo
/
install-adam
< prev
next >
Wrap
Text File
|
1996-05-02
|
6KB
|
210 lines
; ****************************************
; * *
; * Installationsscript für "A.D.AM." *
; * *
; * $VER: 1.3 (C) by J.Reinert *
; * *
; ****************************************
; ****************************************
; Definition der globalen Konstanten
; ****************************************
(set #libsdest "LIBS:")
(set #fontsdest "Fonts:")
(set #fontssource "Fonts")
(set #localedest "Locale:Catalogs")
(set #localesource "Locale/Catalogs")
(set #keysource "Libs/ADAMprog.KEY")
; ****************************************
; Definition der deutschen Texte
; ****************************************
(set #bad-kick
(cat ""@app-name" benötigt Amiga-OS 2.04 oder höher!\n"
"Dies wäre jetzt der richtige Zeitpunkt, Ihren "
"Rechner aufzuwerten. "
)
)
(set #Hardware "Wandler-Platine")
(set #copy-programm "Kopieren des Programmes")
(set #help-programm
(cat "Wenn Sie "@app-name" zum ersten mal installieren, sollten "
"Sie alle aufgeführten Dateien zum kopieren auswählen. Wenn "
"Sie der Meinung sind, daß Sie auf die Anleitung verzichten "
"können, dürfen Sie diese auch links liegen lassen."
)
)
(set #copy-fonts "Kopieren der Zeichensätze")
(set #help-fonts
(cat ""@app-name" benötigt unbedingt alle angezeigten "
"Zeichensätze im \""#fontsdest"\"-Verzeichnis!\n"
"Ohne Zeichensätze wird "@app-name" nicht zu starten sein."
)
)
(set #copy-key "Kopieren des KeyFiles")
(set #help-key
(cat "Sie als registrierter Anwender von "@app-name" müssen Ihre "
"persönliche Schlüsseldatei im \""#libsdest"\"-Verzeichnis "
"installiert haben. Ohne diese Datei können Sie "@app-name" nicht "
"in vollem Umfang nutzen !"
)
)
(set #copy-locale "Kopieren der Kataloge")
(set #help-locale
(cat "Da Sie über mindestens Amiga-OS 2.1 verfügen, kann "@app-name" auf "
"Ihrem Rechner in Ihrer Landessprache betrieben werden. Sollten Sie "
"diesen Teil der Installation überspringen, wird "@app-name" sich in "
"englischer Sprache melden. Englisch ist die Voreinstellung für dieses "
"Programm und wird immer aktiviert, wenn sich kein passender Katalog "
"Ihrer Landessprache im \""#localedest"\"-Verzeichnis befindet"
)
)
; ****************************************
; Version der Workbench bestimmen
; ****************************************
(set #os_version (/ (getversion "libs:version.library") 65536))
; ****************************************
; Beginn der Installation
; ****************************************
(complete 0)
; ****************************************
; Prüfen, ob richtiges Betriebsystem
; ****************************************
(if (< #os_version 37)
(
(abort #bad-kick)
))
(welcome)
; ****************************************
; Zielverzeichnis auswählen lassen
; ****************************************
(set name
(askdir
(prompt "Wohin soll ADAM kopiert werden ?\n Ein Verzeichnis namens \"ADAM\" wird erzeugt")
(help @askdir-help)
(default @default-dest)
)
)
; ****************************************
; Zielverzeichnis um ADAM-Verz. ergänzen
; ****************************************
(set destname (tackon name "ADAM"))
; ****************************************
; Zielverzeichnis erzeugen
; ****************************************
(makedir destname
(prompt "Verzeichnis \""destname"\" anlegen")
(infos)
)
(complete 10)
; ****************************************
; Kopieren der Zeichensätze
; ****************************************
(copyfiles (prompt #copy-fonts)
(help #help-fonts)
(source #fontssource)
(dest #fontsdest)
(pattern "#?")
(fonts)
(confirm "expert")
)
(complete 20)
; ****************************************
; Kopieren des KeyFiles
; ****************************************
(if (exists #keysource)
(copyfiles (prompt #copy-key)
(help #help-key)
(source #keysource)
(dest #libsdest)
(confirm "expert")
)
)
(complete 40)
; ****************************************
; Kopieren der lokalen Kataloge
; ****************************************
(if (> #os_version 37)
(if (exists #localesource)
(if (exists #localedest)
(
(copyfiles
(prompt #copy-locale)
(help #help-locale)
(source #localesource)
(dest #localedest)
(pattern "#?")
(confirm "expert")
)
)
)
)
)
(complete 50)
; ****************************************
; Kopieren des Programmes
; ****************************************
(copyfiles (prompt #copy-programm)
(help #help-programm)
(infos)
(source "Programm")
(dest destname)
(pattern "#?")
(confirm "expert")
)
(complete 100)
; ****************************************
; Aktuelles Verzeichnis setzen
; ****************************************
(set @default-dest
(destname)
)
; *************************************************************************
; End Of Installation-Script
; *************************************************************************